*

*Continuous conditioning circuit with a variable capacitor

***** Parameter definition*******
* gap closing transducer parameters: initial gap, area
.params d0=45e-6
.params S=1e-4

* Mobile electrode sinusoidal motion parameters: amplitude, freq. in Hz
.params X0=40e-6
.params f=100

* Permittivity of the vacuum
.params eps0=8.85e-12

* Parasitic capacitance in series with the transducer
.params Cp=30e-12

*Load resistance
.params RL=10e6

* Bias voltage
.params Vres=5
****************************************

* Fixed capacitors
.params Cres=1e-6
.params Cstore=3e-9

*** Diode model :

.model IdealDiode D(Ron=.1 Roff=1000Meg Vfwd=.01)


********* The netlist:

* Definition of the variable capacitance
Vdisp disp 0 sine ( 0 {X0} {f*2*3.14} 0 0 0 0)
Ecvar Cvar 0 value={Cp+eps0*S/(d0-V(disp))}

* Current generated by the variable capacitor
Cvar var 0 Q=V(Cvar)*x

*Vt var 0 1
* charge pump
Cres res 0 {Cres} ic={Vres} Rpar=1e12
Cstore store 0 {Cstore} Rpar=1e12
d1 res var IdealDiode
d2 var store IdealDiode

******Simulator commands

* Transient simulation
.tran 2 2 uic

** simulation parameters
.options method=gear reltol=1e-6
.end