source: trunk/hal/x86_64/core/hal_cpu.S @ 125

Last change on this file since 125 was 125, checked in by max@…, 7 years ago

implement hal_time_stamp and hal_fence

File size: 2.3 KB
Line 
1/*
2 * hal_cpu.S - Miscellaneous CPU functions
3 *
4 * Copyright (c) 2017 Maxime Villard
5 *
6 * This file is part of ALMOS-MKH.
7 *
8 * ALMOS-MKH is free software; you can redistribute it and/or modify it
9 * under the terms of the GNU General Public License as published by
10 * the Free Software Foundation; version 2.0 of the License.
11 *
12 * ALMOS-MKH is distributed in the hope that it will be useful, but
13 * WITHOUT ANY WARRANTY; without even the implied warranty of
14 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
15 * General Public License for more details.
16 *
17 * You should have received a copy of the GNU General Public License
18 * along with ALMOS-MKH.; if not, write to the Free Software Foundation,
19 * Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA
20 */
21
22#define x86_ASM
23#include <hal_boot.h>
24#include <hal_segmentation.h>
25
26ASM_ENTRY(lgdt)
27        lgdt    (%rdi)
28        /* Reload the prefetch queue */
29        jmp     1f
30        nop
311:      /* Reload stale selectors */
32        movl    $GDT_FIXED_SEL(GDT_KDATA_SEL, SEL_KPL),%eax
33        movl    %eax,%ds
34        movl    %eax,%es
35        movl    %eax,%ss
36        ret
37
38ASM_ENTRY(lidt)
39        lidt    (%rdi)
40        ret
41
42ASM_ENTRY(ltr)
43        ltr     %di
44        ret
45
46ASM_ENTRY(invlpg)
47        invlpg  (%rdi)
48        ret
49
50ASM_ENTRY(sti)
51        sti
52        ret
53
54ASM_ENTRY(cli)
55        cli
56        ret
57
58ASM_ENTRY(rdtsc)
59        xorq    %rax,%rax
60        rdtsc
61        shlq    $32,%rdx
62        orq     %rdx,%rax
63        ret
64
65ASM_ENTRY(in8)
66        movq    %rdi,%rdx
67        xorq    %rax,%rax
68        inb     %dx,%al
69        ret
70
71ASM_ENTRY(out8)
72        movq    %rdi,%rdx
73        movq    %rsi,%rax
74        outb    %al,%dx
75        ret
76
77ASM_ENTRY(rdmsr)
78        movq    %rdi,%rcx
79        xorq    %rax,%rax
80        rdmsr
81        shlq    $32,%rdx
82        orq     %rdx,%rax
83        ret
84
85ASM_ENTRY(wrmsr)
86        movq    %rdi,%rcx
87        movq    %rsi,%rax
88        movq    %rsi,%rdx
89        shrq    $32,%rdx
90        wrmsr
91        ret
92
93ASM_ENTRY(mfence)
94        mfence
95        ret
96
97ASM_ENTRY(rcr2)
98        movq    %cr2,%rax
99        ret
100
101ASM_ENTRY(x86_stop) /* debug only */
102        int     $0x0b
103        ret
104
105/* -------------------------------------------------------------------------- */
106
107ASM_ENTRY(atomic_cas_32)
108        movl    %esi,%eax
109        lock
110        cmpxchgl %edx,(%rdi)
111        /* %eax now contains the old value */
112        ret
113
114ASM_ENTRY(atomic_add_32)
115        movl    %esi,%eax
116        lock
117        xaddl   %eax,(%rdi)
118        /* %eax now contains the old value */
119        ret
120
121ASM_ENTRY(atomic_and_32)
122        movl    (%rdi),%eax
1231:
124        movl    %eax,%ecx
125        andl    %esi,%ecx
126        lock
127        cmpxchgl %ecx,(%rdi)
128        jnz     1b
129        /* %eax now contains the old value */
130        ret
131
132ASM_ENTRY(atomic_or_32)
133        movl    (%rdi),%eax
1341:
135        movl    %eax,%ecx
136        orl     %esi,%ecx
137        lock
138        cmpxchgl %ecx,(%rdi)
139        jnz     1b
140        /* %eax now contains the old value */
141        ret
142
Note: See TracBrowser for help on using the repository browser.