source: trunk/hal/x86_64/core/hal_cpu.S @ 365

Last change on this file since 365 was 365, checked in by max@…, 4 years ago

Remove debug function.

File size: 4.3 KB
Line 
1/*
2 * hal_cpu.S - Miscellaneous CPU functions
3 *
4 * Copyright (c) 2017 Maxime Villard
5 *
6 * This file is part of ALMOS-MKH.
7 *
8 * ALMOS-MKH is free software; you can redistribute it and/or modify it
9 * under the terms of the GNU General Public License as published by
10 * the Free Software Foundation; version 2.0 of the License.
11 *
12 * ALMOS-MKH is distributed in the hope that it will be useful, but
13 * WITHOUT ANY WARRANTY; without even the implied warranty of
14 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
15 * General Public License for more details.
16 *
17 * You should have received a copy of the GNU General Public License
18 * along with ALMOS-MKH; if not, write to the Free Software Foundation,
19 * Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA
20 */
21
22#define x86_ASM
23#include <hal_boot.h>
24#include <hal_segmentation.h>
25#include <hal_register.h>
26#include <hal_kentry.h>
27
28ASM_ENTRY(lgdt)
29        lgdt    (%rdi)
30        /* Reload the prefetch queue */
31        jmp     1f
32        nop
331:      /* Reload stale selectors */
34        movl    $GDT_FIXED_SEL(GDT_KDATA_SEL, SEL_KPL),%eax
35        movl    %eax,%ds
36        movl    %eax,%es
37        movl    %eax,%ss
38        ret
39
40ASM_ENTRY(lidt)
41        lidt    (%rdi)
42        ret
43
44ASM_ENTRY(ltr)
45        ltr     %di
46        ret
47
48ASM_ENTRY(invlpg)
49        invlpg  (%rdi)
50        ret
51
52ASM_ENTRY(sti)
53        sti
54        ret
55
56ASM_ENTRY(cli)
57        cli
58        ret
59
60ASM_ENTRY(rdtsc)
61        xorq    %rax,%rax
62        rdtsc
63        shlq    $32,%rdx
64        orq     %rdx,%rax
65        ret
66
67ASM_ENTRY(in8)
68        movq    %rdi,%rdx
69        xorq    %rax,%rax
70        inb     %dx,%al
71        ret
72
73ASM_ENTRY(in16)
74        movq    %rdi,%rdx
75        xorq    %rax,%rax
76        inw     %dx,%ax
77        ret
78
79ASM_ENTRY(out8)
80        movq    %rdi,%rdx
81        movq    %rsi,%rax
82        outb    %al,%dx
83        ret
84
85ASM_ENTRY(out16)
86        movq    %rdi,%rdx
87        movq    %rsi,%rax
88        outw    %ax,%dx
89        ret
90
91ASM_ENTRY(rdmsr)
92        movq    %rdi,%rcx
93        xorq    %rax,%rax
94        rdmsr
95        shlq    $32,%rdx
96        orq     %rdx,%rax
97        ret
98
99ASM_ENTRY(wrmsr)
100        movq    %rdi,%rcx
101        movq    %rsi,%rax
102        movq    %rsi,%rdx
103        shrq    $32,%rdx
104        wrmsr
105        ret
106
107ASM_ENTRY(mfence)
108        mfence
109        ret
110
111ASM_ENTRY(rcr0)
112        movq    %cr0,%rax
113        ret
114
115ASM_ENTRY(rcr2)
116        movq    %cr2,%rax
117        ret
118
119ASM_ENTRY(rcr3)
120        movq    %cr3,%rax
121        ret
122
123ASM_ENTRY(rcr4)
124        movq    %cr4,%rax
125        ret
126
127ASM_ENTRY(lcr4)
128        movq    %rdi,%cr4
129        ret
130
131ASM_ENTRY(cpuid)
132        movq    %rbx,%r8
133        movq    %rdi,%rax
134        movq    %rsi,%rcx
135        movq    %rdx,%rsi
136        cpuid
137        movl    %eax,0(%rsi)
138        movl    %ebx,4(%rsi)
139        movl    %ecx,8(%rsi)
140        movl    %edx,12(%rsi)
141        movq    %r8,%rbx
142        ret
143
144/*
145 * To flush all TLB entries, we must re-set the CR4_PGE flag in %cr4.
146 */
147ASM_ENTRY(tlbflushg)
148        movq    %cr4,%rax
149        movq    %rax,%rdx
150        andq    $~CR4_PGE,%rdx
151        movq    %rdx,%cr4
152        movq    %rax,%cr4
153        ret
154
155ASM_ENTRY(tlbflush)
156        movq    %cr3,%rax
157        movq    %rax,%cr3
158        ret
159
160ASM_ENTRY(clts)
161        clts
162        ret
163
164ASM_ENTRY(stts)
165        movq    %cr0,%rax
166        orq     $CR0_TS,%rax
167        movq    %rax,%cr0
168        ret
169
170ASM_ENTRY(pause)
171        pause
172        ret
173
174ASM_ENTRY(wbinvd)
175        wbinvd
176        ret
177
178/* -------------------------------------------------------------------------- */
179
180ASM_ENTRY(cpu_context_switch)
181        pushq   %r12
182        pushq   %r13
183
184        movq    %rdi,%r13       /* oldctx */
185        movq    %rsi,%r12       /* newctx */
186
187        /*
188         * Save the current stack in %rdx, and switch to the trap frame of
189         * the old thread.
190         */
191        movq    %rsp,%rdx
192        movq    CTX_TF(%r13),%rsp
193        addq    $TF_SIZE,%rsp   /* end of the structure */
194
195        /*
196         * Save the TLS intr flag, and set the new one.
197         */
198        movq    TLSVAR(INTR),%rax
199        movq    %rax,CTX_INTR(%r13)
200        movq    CTX_INTR(%r12),%rax
201        movq    %rax,TLSVAR(INTR)
202
203        /* Build the trap frame */
204        movl    %ss,%eax
205        pushq   %rax            /* tf_ss */
206        pushq   %rdx            /* tf_rsp */
207        pushfq                  /* tf_rflags */
208        movl    %cs,%eax
209        pushq   %rax            /* tf_cs */
210        movabsq $thr_resume,%rax
211        pushq   %rax            /* tf_rip */
212        pushq   $0              /* tf_err */
213        pushq   $T_ASTFLT       /* tf_trapno */
214        INTR_SAVE_REGS
215
216        /* Switch rsp0 */
217        movq    CTX_RSP0(%r12),%rax
218        movq    TLSVAR(RSP0),%rdx
219        movq    %rax,(%rdx)
220
221        /* Switch to the new trap frame */
222        movq    CTX_TF(%r12),%rsp
223
224        /*
225         * Restore the context, and jump into the new thread.
226         */
227        INTR_RESTORE_REGS
228        addq    $16,%rsp
229        iretq
230
231thr_resume:
232        /*
233         * Only pop %r12 and %r13, and return.
234         */
235        popq    %r13
236        popq    %r12
237
238        ret
239
240/* -------------------------------------------------------------------------- */
241
242ASM_ENTRY(atomic_cas_32)
243        movl    %esi,%eax
244        lock
245        cmpxchgl %edx,(%rdi)
246        /* %eax now contains the old value */
247        ret
248
249ASM_ENTRY(atomic_add_32)
250        movl    %esi,%eax
251        lock
252        xaddl   %eax,(%rdi)
253        /* %eax now contains the old value */
254        ret
255
256ASM_ENTRY(atomic_and_32)
257        movl    (%rdi),%eax
2581:
259        movl    %eax,%ecx
260        andl    %esi,%ecx
261        lock
262        cmpxchgl %ecx,(%rdi)
263        jnz     1b
264        /* %eax now contains the old value */
265        ret
266
267ASM_ENTRY(atomic_or_32)
268        movl    (%rdi),%eax
2691:
270        movl    %eax,%ecx
271        orl     %esi,%ecx
272        lock
273        cmpxchgl %ecx,(%rdi)
274        jnz     1b
275        /* %eax now contains the old value */
276        ret
277
Note: See TracBrowser for help on using the repository browser.