source: trunk/libs/newlib/src/libgloss/mips/idtecoff.ld @ 444

Last change on this file since 444 was 444, checked in by satin@…, 6 years ago

add newlib,libalmos-mkh, restructure shared_syscalls.h and mini-libc

File size: 2.0 KB
Line 
1/* The following TEXT start address leaves space for the monitor
2   workspace. i.e. the NEC VR4300 (IDT) first free address is actually
3   0xa001af20. */
4
5ENTRY(_start)
6STARTUP(crt0.o)
7OUTPUT_ARCH("mips:4000")
8OUTPUT_FORMAT("ecoff-bigmips", "ecoff-bigmips", "ecoff-littlemips")
9GROUP(-lc -lidt -lgcc)
10SEARCH_DIR(.)
11__DYNAMIC  =  0;
12
13/*
14 * Allocate the stack to be at the top of memory, since the stack
15 * grows down
16 */
17PROVIDE (__stack = 0);
18/* PROVIDE (__global = 0); */
19
20/*
21 * Initalize some symbols to be zero so we can reference them in the
22 * crt0 without core dumping. These functions are all optional, but
23 * we do this so we can have our crt0 always use them if they exist.
24 * This is so BSPs work better when using the crt0 installed with gcc.
25 * We have to initalize them twice, so we multiple object file
26 * formats, as some prepend an underscore.
27 */
28PROVIDE (hardware_exit_hook = 0);
29PROVIDE (hardware_hazard_hook = 0);
30PROVIDE (hardware_init_hook = 0);
31PROVIDE (software_init_hook = 0);
32
33SECTIONS
34{       
35  . = 0xA0020000;
36  .text : {
37     _ftext = . ;
38    KEEP (*(.init))
39     eprol  =  .;
40    *(.text)
41    *(.text.*)
42    *(.gnu.linkonce.t.*)
43    *(.mips16.fn.*)
44    *(.mips16.call.*)
45    PROVIDE (__runtime_reloc_start = .);
46    *(.rel.sdata)
47    PROVIDE (__runtime_reloc_stop = .);
48    KEEP (*(.fini))
49     etext  =  .;
50     _etext  =  .;
51  }
52  . = .;
53  .rdata : {
54    *(.rdata)
55    *(.rodata)
56    *(.rodata.*)
57    *(.gnu.linkonce.r.*)
58  }
59   _fdata = ALIGN(16);
60  .data : {
61    *(.data)
62    *(.data.*)
63    *(.gnu.linkonce.d.*)
64    CONSTRUCTORS
65  }
66  . = ALIGN(8);
67  _gp = . + 0x8000;
68  __global = _gp;
69  .lit8 : {
70    *(.lit8)
71  }
72  .lit4 : {
73    *(.lit4)
74  }
75  .sdata : {
76    *(.sdata)
77    *(.sdata.*)
78    *(.gnu.linkonce.s.*)
79  }
80  . = ALIGN(4);
81   edata  =  .;
82   _edata  =  .;
83   _fbss = .;
84  .sbss : {
85    *(.sbss)
86    *(.sbss.*)
87    *(.gnu.linkonce.sb.*)
88    *(.scommon)
89  }
90  .bss : {
91    _bss_start = . ;
92    *(.bss)
93    *(.bss.*)
94    *(.gnu.linkonce.b.*)
95    *(COMMON)
96  }
97   end = .;
98   _end = .;
99}
Note: See TracBrowser for help on using the repository browser.